0b2cba4e99
Don't poll server when page isn't visible. Install and use the jquery-visibility plugin. Change-Id: I377f2ebe2385668a93d46d31ddf2ec5744f8d26b Reviewed-on: https://review.openstack.org/18606 Approved: Jeremy Stanley <fungi@yuggoth.org> Reviewed-by: Jeremy Stanley <fungi@yuggoth.org> Tested-by: Jenkins
106 lines
3.0 KiB
Puppet
106 lines
3.0 KiB
Puppet
# == Class: openstack_project::zuul
|
|
#
|
|
class openstack_project::zuul(
|
|
$vhost_name = $::fqdn,
|
|
$jenkins_host = '',
|
|
$jenkins_url = '',
|
|
$jenkins_user = '',
|
|
$jenkins_apikey = '',
|
|
$gerrit_server = '',
|
|
$gerrit_user = '',
|
|
$zuul_ssh_private_key = '',
|
|
$url_pattern = '',
|
|
$sysadmins = []
|
|
) {
|
|
|
|
$rules = [ "-m state --state NEW -m tcp -p tcp --dport 8001 -s ${jenkins_host} -j ACCEPT" ]
|
|
|
|
class { 'openstack_project::server':
|
|
iptables_public_tcp_ports => [80],
|
|
iptables_rules4 => $rules,
|
|
sysadmins => $sysadmins,
|
|
}
|
|
|
|
class { '::zuul':
|
|
vhost_name => $vhost_name,
|
|
jenkins_server => $jenkins_url,
|
|
jenkins_user => $jenkins_user,
|
|
jenkins_apikey => $jenkins_apikey,
|
|
gerrit_server => $gerrit_server,
|
|
gerrit_user => $gerrit_user,
|
|
zuul_ssh_private_key => $zuul_ssh_private_key,
|
|
url_pattern => $url_pattern,
|
|
push_change_refs => false,
|
|
status_url => "http://${::fqdn}/",
|
|
}
|
|
|
|
file { '/etc/zuul/layout.yaml':
|
|
ensure => present,
|
|
source => 'puppet:///modules/openstack_project/zuul/layout.yaml',
|
|
notify => Exec['zuul-reload'],
|
|
}
|
|
file { '/etc/zuul/openstack_functions.py':
|
|
ensure => present,
|
|
source => 'puppet:///modules/openstack_project/zuul/openstack_functions.py',
|
|
notify => Exec['zuul-reload'],
|
|
}
|
|
file { '/etc/zuul/logging.conf':
|
|
ensure => present,
|
|
source => 'puppet:///modules/openstack_project/zuul/logging.conf',
|
|
notify => Exec['zuul-reload'],
|
|
}
|
|
|
|
class { '::recheckwatch':
|
|
gerrit_server => $gerrit_server,
|
|
gerrit_user => $gerrit_user,
|
|
recheckwatch_ssh_private_key => $zuul_ssh_private_key,
|
|
}
|
|
|
|
file { '/var/lib/recheckwatch/scoreboard.html':
|
|
ensure => present,
|
|
source => 'puppet:///modules/openstack_project/zuul/scoreboard.html',
|
|
require => File['/var/lib/recheckwatch'],
|
|
}
|
|
|
|
file { '/var/lib/zuul/www':
|
|
ensure => directory,
|
|
require => File['/var/lib/zuul'],
|
|
}
|
|
|
|
file { '/var/lib/zuul/www/index.html':
|
|
ensure => present,
|
|
source => 'puppet:///modules/openstack_project/zuul/status.html',
|
|
require => File['/var/lib/zuul/www'],
|
|
}
|
|
|
|
package { 'libjs-jquery':
|
|
ensure => present,
|
|
}
|
|
|
|
file { '/var/lib/zuul/www/jquery.min.js':
|
|
ensure => link,
|
|
target => '/usr/share/javascript/jquery/jquery.min.js',
|
|
require => [File['/var/lib/zuul/www'],
|
|
Package['libjs-jquery']],
|
|
}
|
|
|
|
file { '/var/lib/zuul/www/status.js':
|
|
ensure => present,
|
|
source => 'puppet:///modules/openstack_project/zuul/status.js',
|
|
require => File['/var/lib/zuul/www'],
|
|
}
|
|
|
|
vcsrepo { '/opt/jquery-visibility':
|
|
ensure => latest,
|
|
provider => git,
|
|
revision => 'master',
|
|
source => 'https://github.com/mathiasbynens/jquery-visibility.git',
|
|
}
|
|
|
|
file { '/var/lib/zuul/www/jquery-visibility.min.js':
|
|
ensure => link,
|
|
target => '/opt/jquery-visibility/jquery-visibility.min.js',
|
|
require => File['/var/lib/zuul/www'],
|
|
}
|
|
}
|